jeanphiBlog

FLASH CS4 : Fullscreen AS3...

Exemple basique de Video en fullscreen en AS3...

Le code :

import flash.events.MouseEvent;
var fullscreen:Boolean=false;
stage.addEventListener(MouseEvent.CLICK, clickHandler);
function clickHandler(event:MouseEvent):void {
if (! fullscreen) {
fullscreen=true;
stage"displayState"="fullScreen";
} else {
fullscreen=false;
stage"displayState"="normal";
}
}

le lien pour voir

FLASH CS4 : Publication d'un swf � 100% + footer en flash...

Souvent cette question revient sur Mediabox ...
Comment int�grer un "footer" sur une animation flash publi�e � 100%. (tr�s chiant � faire en html � base de div)

Le truc le plus simple est d'int�grer directement ce footer dans le flash et de publier l'animation � 100%.

Voici un exemple en code et en visuel :

stage.scaleMode=StageScaleMode.NO_SCALE;
stage.align=StageAlign.TOP_LEFT;
fond.width=stage.stageWidth;
fond.height=stage.stageHeight;
avat.x=stage.stageWidth-70;
avat.y=stage.stageHeight-20;
footer.x=0;
footer.y=stage.stageHeight;
footer.barre.width=stage.stageWidth;
stage.addEventListener(Event.RESIZE, stageResized);
function stageResized(event:Event):void {
fond.width=stage.stageWidth;
fond.height=stage.stageHeight;
footer.x=0;
footer.y=stage.stageHeight;
footer.barre.width=stage.stageWidth;
avat.x=stage.stageWidth-70;
avat.y=stage.stageHeight-20;
}

le visuel ici...
les sources ici...
On recr�� pas la roue, mais �a peut aider :)
avec un tween �a donne �a...

FLASH CS5 : Pas de beta publique pour Flash Professional CS5...

La nouvelle est tomb�e hier sur le blog Adobe et Adobe a chang� ses plans; il n'y aura donc pas de beta publique pour Flash Professional CS5.

Plus de d�tails dans ce post de Adrian Ludwig...

FLASH CS4 : TileList component, popup centr�...

Suite � mon poste pr�c�dent, traitant du composant TileList sur Flash Developper Center, j'ai un peu optimis� le truc...

Maintenant :
l'image s'ouvre dans un popup qui s'adapte � la taille de l'image
le popup est centr�
le nom de l'image s'affiche dans la window
le javascript est int�gr� dans flash

l'exemple en ligne ici
le fichier source ici

FLASH CS4 : Popup AS3 ExternalInterface...

Comment cr�er des Popups javascript en as3...

Le cas le plus simple :

import flash.external.ExternalInterface;
stage.align = StageAlign.TOP_LEFT;
stage.scaleMode = StageScaleMode.NO_SCALE;
var monJavaScript:XML = 
<script>
<![CDATA[
function global(){
function createpopup (){ 
window.open("http://jeanphiblog.media-box.net","win","height=400,width=600,toolbar=no,scrollbars=yes"); 
}; 
createpopup(); 
}
]]>
</script>;;
btn.addEventListener(MouseEvent.CLICK,onClick);
function onClick(e:Event):void {
ExternalInterface.call(monJavaScript);
}

exemple1

Le deuxieme exemple nous permet de cr�er un popup centr� dans l'�cran :

import flash.external.ExternalInterface;
stage.align = StageAlign.TOP_LEFT;
stage.scaleMode = StageScaleMode.NO_SCALE;
var monJavaScript:XML = 
<script>
<![CDATA[
function global(){
function popupcentree(page,largeur,hauteur,options) 
{ 
var top=(screen.height-hauteur)/2; 
var left=(screen.width-largeur)/2;
window.open(page,"","top="+top+",left="+left+",width="+largeur+",height="+hauteur+","+options); 
} 
popupcentree("http://jeanphiblog.media-box.net",800,600,"menubar=no,scrollbars=no,statusbar=no");
}
]]>
</script>;
btn.addEventListener(MouseEvent.CLICK,onClick);
function onClick(e:Event):void {
ExternalInterface.call(monJavaScript);
}

exemple2

La seule chose � modifier dans votre page html sera le param�tre de : allowScriptAccess
Il faudra remplacer tous les samedomain par always...

FLASH CS4 : TileList component, enlarge thumbnails...

Suite � une demande faite par un des lecteurs, dans ce tutorial sur Flash Developper Center, j'ai rajout� dans le code initial, le fait de pouvoir afficher l'image en grand en cliquant sur les vignettes du composant TileList.

J'ai seulement rajout� un composant Loader dans la biblioth�que et j'ai modifi� le code ainsi :

import fl.controls.TileList;
import fl.controls.ScrollBarDirection;
import fl.containers.UILoader;
stage.align = StageAlign.TOP_LEFT;
stage.scaleMode = StageScaleMode.NO_SCALE;
// create TileList instance
var myTileList:TileList = new TileList();

// add content to the TileList
myTileList.addItem({label:"Montreal", source:"http://www.helpexamples.com/images/montreal/images/IMG_5057.jpg"});
myTileList.addItem({label:"Swan", source:"http://www.helpexamples.com/flash/images/gallery1/images/pic11.jpg"});
myTileList.addItem({label:"Sunset", source:"http://www.helpexamples.com/flash/images/gallery1/images/pic14.jpg"});
myTileList.addItem({label:"Gate", source:"http://www.helpexamples.com/flash/images/gallery2/images/IMG_1592.jpg"});
myTileList.direction=ScrollBarDirection.HORIZONTAL;// set scroll direction

// set column and row values
myTileList.columnWidth=200;
myTileList.rowHeight=140;
myTileList.columnCount=1;
myTileList.rowCount=2;
myTileList.width=200;
myTileList.height=295;
myTileList.x=10;
myTileList.y=10;

// add to the display (Stage)
addChild(myTileList);
myTileList.addEventListener(Event.CHANGE, thumbnailClicked);
function thumbnailClicked(event:Event):void {
myUILoader.source=event.target.selectedItem.source;
}
var myUILoader:UILoader = new UILoader();
myUILoader.autoLoad=true;
myUILoader.scaleContent=false;
myUILoader.move(220, 10);
addChild(myUILoader);

Voir l'exemple en ligne......
T�l�charger le fichier Flash CS4...

fLASH CS4 : BitmapData > ByteArray > load raw format...

Suite au billet pr�c�dent, voici comment loader ce fichier raw dans Flash...

le code :

var ldr:URLLoader= new URLLoader();
ldr.dataFormat=URLLoaderDataFormat.BINARY;// ** make sure you do this **
ldr.addEventListener(Event.COMPLETE, on_fileLoad);
ldr.load(new URLRequest("image.bmp"));
function on_fileLoad(evt:Event):void {
if (evt.type==Event.COMPLETE) {
var data:ByteArray=URLLoader(evt.target).data as ByteArray;
if (data) {
try {
data.uncompress();
} catch (e:Error) {
}
// data is now the uncompressed byte array
// ... process data ...
var width:int=data.readUnsignedInt();// first 4 bytes
// after data.uncompress()
var height:int = ((data.length - 4) / 4) / width;
// (data.length - 4) ** byte array less the first four bytes gives the representation of the bitmap **
// ((data.length - 4) / 4) ** length of the representation is divided by four because each pixel takes four bytes **
// ((data.length - 4) / 4) / width ** remember, it is a rectangle, so we can get the height this way **
var bmd:BitmapData=new BitmapData(width,height,false,0);// 32 bit transparent bitmap
bmd.setPixels(bmd.rect, data);// position of data is now at 5th byte
var bm:Bitmap=new Bitmap(bmd);
addChild(bm);
}
}
}

Merci � ghostwire pour la piste...

FLASH CS4 : BitmapData > ByteArray > save raw format...

Comment sauver en "brut" (raw), une image BitmapData...

Voici un exemple :

import flash.net.FileReference;
var myFileRefSave:FileReference;
myFileRefSave = new FileReference();

var cam:Camera=Camera.getCamera();
vid.attachCamera(cam);
cam.setMode(320, 240, 10);

sauve.addEventListener(MouseEvent.CLICK,onClick);
function onClick(evt:MouseEvent):void {
var bitmap:BitmapData=new BitmapData(vid.width,vid.height,false);
var ma:Matrix = new Matrix();
ma.scale(2,2);
bitmap.draw(vid,ma);
var bitmapImage:Bitmap=new Bitmap(bitmap);
var bytes:ByteArray = new ByteArray();
bytes.writeUnsignedInt(bitmapImage.bitmapData.width);
bytes.writeBytes(bitmapImage.bitmapData.getPixels(bitmapImage.bitmapData.rect));
bytes.compress();
myFileRefSave.save(bytes,"image.bmp");

}

Bien �videmment cela ne sert pas � grand chose si ce n'est que de sauver un fichier brut inutilisable sur votre DD.
le lien pour tester
Par contre, il est possible, par la suite de loader cette image dans Flash sans m�me qu'elle soit r�encod�e.
A voir dans le deuxieme billet :)

FLASH CS5 : Cr�er et compiler une application iphone avec Flash CS5...

Merci � Lee Brimelow pour ce tutorial video, dans lequel il nous explique comment utiliser Flash CS5 pour d�velopper et compiler une application Flash en application Iphone.

Le lien vers le tutorial.

FLASH CS4 : Sound extract, Filereference save, bytesarray to WAV...

ou comment loader un mp3, en extraire un morceau et l'enregistrer en wav sur son bureau gr�ce � la classe WAVEncoder (merci Mediabox)...

voici le code

[actionscript]

import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.events.SampleDataEvent;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.net.FileReference;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.utils.ByteArray;
import flash.utils.Endian;
import pack.WAVEncoder;


var _sound:Sound;
var _channel:SoundChannel;
var _dynSound:Sound;
var _samplesOut:ByteArray;

if (stage) {
	init();
} else {
	addEventListener(Event.ADDED_TO_STAGE, init);


}
function init(e:Event = null):void {
	removeEventListener(Event.ADDED_TO_STAGE, init);
	//

	var tf:TextField = new TextField ( );
	tf.autoSize=TextFieldAutoSize.LEFT;
	tf.text="Clic sur la scene pour enregistrer le son";
	addChild( tf );

	_samplesOut = new ByteArray ( ) ;
	_samplesOut.endian=Endian.LITTLE_ENDIAN;

	_sound=new Sound(new URLRequest("snd/zic.mp3"));
	_sound.addEventListener( Event.COMPLETE, _soundLoadedHandler );

	stage.addEventListener( MouseEvent.CLICK, _saveFileHandler );

}

function _soundLoadedHandler(e:Event):void {
	_sound.play();
	_dynSound = new Sound ( ) ;
	_dynSound.addEventListener( SampleDataEvent.SAMPLE_DATA, _sampleDataHandler );
	_channel=_dynSound.play();
}

function _sampleDataHandler(e:SampleDataEvent):void {
	// J'extraie 5 secondes � partir de 4 secondes du d�but
	_sound.extract( _samplesOut, 44100 * 5,44100 * 4 );
}

function _saveFileHandler(e:Event):void {
	var encoder:WAVEncoder = new WAVEncoder ( );

	var fileRef:FileReference = new FileReference ( );

	fileRef.save( encoder.addHeaders ( testConvert(_samplesOut) ), "monSon.wav" );
}

function testConvert( p:ByteArray ):ByteArray {
	var ba:ByteArray = new ByteArray ( );
	ba.endian=Endian.LITTLE_ENDIAN;
	p.position=0;

	while ( p.position < p.length ) {
		ba.writeShort( p.readFloat ( ) * 32767);
	}

	return ba;
}

le lien pour tester ici les sources > ici