En effet, il suffit tout simplement de choisir un Skin (comme par exemple SkinUnderPlaySeekFullscreen) permettant le Fullscreen et d'indiquer dans les Paramètres de publication : Flash seulement - Autorisation du plein écran.
Aucun code n'est nécessaire.

Exemple en image

Pour ceux qui n'utilisent pas de composants, il est toujouurs possible d'utiliser l'objet Stage et la propriété displayState.

displayState propriété
displayState:String read-write
Version du langage : ActionScript 3.0
Version du lecteur : Flash Player 9.0.28.0
Une valeur de la classe StageDisplayState qui spécifie l'état d'affichage à utiliser. Les valeurs suivantes sont prises en charge :

StageDisplayState.FULL_SCREEN Définit Flash Player de façon à exploiter toute la largeur de l'écran.
StageDisplayState.NORMAL Rétablit le mode d'affichage standard du lecteur.
Le comportement de mise à l'échelle du clip en mode plein écran est déterminé par le paramètre scaleMode (défini à l'aide de la propriété Stage.scaleMode ou des paramètres de la balise embed du fichier HTML). Lorsque la propriété scaleMode est définie sur noScale pendant la transition de Flash Player vers le mode plein écran, les propriétés width et height sont mises à jour. Ensuite, Flash Player distribue l'événement Stage.resize.

Les restrictions suivantes s'appliquent aux fichiers SWF qui s'exécutent au sein d'une page HTML (non pas ceux qui utilisent le lecteur Flash Player autonome) :

Pour activer le mode plein écran, ajoutez le paramètre allowFullScreen aux balises object et embed de la page HTML qui inclut le fichier SWF, avec allowFullScreen défini sur "true", comme indiqué dans l'exemple suivant :
<param name="allowFullScreen" value="true" />

        ...
 <embed src="example.swf" allowFullScreen="true" ... >

Une page HTML peut également utiliser un script pour générer des balises d'imbrication de fichiers SWF. Vous ne pouvez pas modifier le script de façon à insérer les paramètres allowNetworking corrects. Les pages HTML générées par Flash et FlexBuilder utilisent la fonction AC_FL_RunContent() pour imbriquer des références aux fichiers SWF, et vous devez ajouter le paramètre allowNetworking, comme dans l'exemple suivant :

AC_FL_RunContent( ... "allowFullScreen", "true", ... )
Le mode plein écran est initié en réponse à un clic de souris ou une pression de touche de l'utilisateur, le clip ne peut pas modifier Stage.displayState sans interaction de l'utilisateur. Lorsque Flash Player est en mode plein écran, toutes les entrées du clavier sont désactivées (sauf les raccourcis clavier qui désactivent le mode plein écran). La boîte de dialogue Flash Player se superpose au clip lorsque les utilisateurs activent le mode plein écran pour informer les utilisateurs que le mode plein écran est actif et qu'ils peuvent appuyer sur la touche Echap pour mettre fin au mode plein écran.

Implémentation 

   public function get displayState():String
 
   public function set displayState(value:String):void

Lance
SecurityError — L'appel de la propriété displayState d’un objet Stage renvoie une exception pour tout appelant qui n’appartient pas au même sandbox de sécurité que le propriétaire de l’objet Stage (le fichier SWF principal). Pour éviter cette situation, le propriétaire de l’objet Stage peut accorder une autorisation au domaine de l'appelant en exécutant la méthode Security.allowDomain() ou Security.allowInsecureDomain(). Pour plus d’informations, consultez le chapitre « Sécurité » du manuel Programmation d’ActionScript 3.0. La définition de la propriété displayState lorsque la boîte de dialogue de définition des paramètres, sans réponse utilisateur, ou si l'attribut allowFullScreen de la balise param ou embed n'est pas défini sur true renvoie une erreur de sécurité.

Voir aussi

flash.display.StageDisplayState
Stage.scaleMode
flash.events.FullScreenEvent
flash.events.Event.RESIZE
La sécurité dans Flash Player

Exemple
Utilisation des exemples

L'exemple suivant montre de manière interactive comment créer une application plein écran en modifiant la propriété displayState.
Remarque : Le mode plein écran peut être déclenché dans certaines situations, par exemple si l'utilisateur a cliqué ou appuyé sur une touche, en raison de restrictions de sécurité. La propriété allowFullScreen doit être définie sur true lorsqu'elle s'exécute dans un navigateur.

package {

   import flash.display.Sprite;
   import flash.display.Stage;
   import flash.events.*;
   import flash.net.NetConnection;
   import flash.net.NetStream;
   import flash.media.Video;
   
   public class FullScreenExample extends Sprite
   {
       private var videoURL:String = "testVideo.flv";
       private var connection:NetConnection;
       private var stream:NetStream;
       private var video:Video;        
       
       public function FullScreenExample() {
           connection = new NetConnection();
           connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
           connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
           connection.connect(null);
           
           loaderInfo.addEventListener(Event.INIT, createMouseListener);            
       }
       private function createMouseListener(event:Event):void {
           stage.addEventListener(MouseEvent.CLICK,toggleFullScreen);
       }        
       
       private function toggleFullScreen(event:MouseEvent):void {
           switch(stage.displayState) {
               case "normal":
                   stage.displayState = "fullScreen";    
                   break;
               case "fullScreen":
               default:
                   stage.displayState = "normal";    
                   break;
           }
       }    
       
       // Video related:
       private function netStatusHandler(event:NetStatusEvent):void {
           switch (event.info.code) {
               case "NetConnection.Connect.Success":
                   connectStream();
                   break;
               case "NetStream.Play.StreamNotFound":
                   trace("Unable to locate video: " + videoURL);
                   break;
           }
       }
       private function connectStream():void {
           var stream:NetStream = new NetStream(connection);
           stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
           stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
           video = new Video(stage.stageWidth,stage.stageHeight);
           video.attachNetStream(stream);
           stream.play(videoURL);
           addChild(video);
       }
       private function securityErrorHandler(event:SecurityErrorEvent):void {
           trace("securityErrorHandler: " + event);
       }
       private function asyncErrorHandler(event:AsyncErrorEvent):void {
           // ignore AsyncErrorEvent events.
       }            
   }

}